(* Below is a general form of a monic proper Zolotarev polynomial Z5s of degree n = 5 *)

Z5s[x_]=a05+a15 x+a25 x^2+a35 x^3+(-5 s) x^4+x^5;

(* Two interpolatory conditions are expolited, for n = 5 odd, see Theorem 1.1; L5 denotes the (least) deviation from zero of Z5s on [-1,1] *)

Solve[{Z5s[1]+L5==0,Z5s[-1]+L5==0},{a05,a15}]

(* After insertion, there results an amended monic proper Zolotarev polynomial Z5sa *)

Z5sa[x_]=Z5s[x]/.{a05->-a25-L5+5 s,a15->-1-a35}

(* The Abel-Pell DE (8) for n = 5 is expolited as well as a further identity from Theorem 1.1, yielding the list List1 *)

List1=Drop[CoefficientList[Numerator[Together[((1-x^2)(x-α)(x-β)/(25(x-γ)^2)D[Z5sa[x],x]^2)-(L5^2-Z5sa[x]^2)]],x]/.γ->(1/2) (-2 s+α+β),-1]//Simplify;

(* Two constraints are added and List1 is concatenated with List2 to yield list LL *)

List2={Z5sa[α]+L5,Z5sa[β]-L5}//Simplify;

LL=Join[List1,List2]//Simplify;

(* LL contains 13 elements which are polynomials in the variables a25,a35,L5,s,α,β  *)

Length[LL]

Union[Cases[LL,_Symbol,Infinity]]

(* In some of the elements of LL the variables a25, a35, L5 (entering in the coefficients of Z5sa) occur linearly;
starting from the end of LL, search for that element which contains a35 linearly but none of the variables a25 and L5;
the last but two element of LL has this property; equate to zero and solve for a35; considering a35 as known, proceed analogously for a25 and L5 *)

linrule1=Solve[LL[[-3]]==0,a35][[1]]//Simplify

linrule2=Solve[(LL[[-2]]/.linrule1)==0,a25][[1]]//Simplify

linrule3=Solve[(LL[[-1]]/.linrule1/.linrule2)==0,L5][[1]]//Simplify

(* Insert the so recursively determined variables a25,a35,L5 (which depend solely on s, α, β) into Z5sa *)

Z5sa[x]

Z5sa[x]/.linrule1/.linrule2/.linrule3//Simplify;

quinticcoefflist=CoefficientList[%,x]//Simplify

(* Result is list of coefficients (depending solely on s,α,β) of tentative Zolotarev polynomial (Subscript[Z, 5,α,β]) = (Subscript[R, 5,α,β]) *)

(* To determine for the givenn = 5 and s = (Subscript[s, 0]) the concrete (Subscript[α, 0]), (Subscript[β, 0]), and hence the concrete coefficients of (Subscript[R, 5,α,β]), it is suggested to deploy the Variant 3; choosing e.g. (Subscript[s, 0]) = 41/(25 Sqrt[145]) one so gets 
α = (Subscript[α, 0]) = 67/(5 Sqrt[145]) and β = (Subscript[β, 0]) = 77/(5 Sqrt[145]) and hence (after insertion) the list of coefficients of (Subscript[Z, 5,(Subscript[s, 0])]) *)

quinticcoefflist/.{s->41/(25Sqrt[145]),α->67/(5Sqrt[145]),β->77/(5Sqrt[145])}

(* Generating algorithmically the reduced relation curve H56(α,β) and s5(α,β), see Section 2.4, yields *)

H56=64-80 α^2+44 α^4+α^6+96 α β-16 α^3 β+6 α^5 β-16 β^2+104 α^2 β^2-29 α^4 β^2-80 α β^3+36 α^3 β^3-52 β^4-9 α^2 β^4-10 α β^5+5 β^6;
s5=((16+9 (α^4)-8 (α^3) β-8 (β^2)+5 (β^4)-6 (α^2) (4+(β^2)))/(20 ((α^3)-(α^2) β+β (-4+(β^2))-α (4+(β^2)))));

(* Below ((Subscript[α, 0]), (Subscript[β, 0])) is displayed as point of intersection of the planar algebraic curves H56(α,β)=0 and s5(α,β)-(Subscript[s, 0]) =0 *)

ContourPlot[Evaluate[{H56==0,s5-41/(25Sqrt[145])==0}],{α,0,5},{β,0,5},Epilog->Point[{67/(5Sqrt[145]),77/(5Sqrt[145])}]]

(* Below is indicated the algorithmic computation, for n = 5, of the Malyshev polynomials F6s(α) and G6s(β), which have positive leading coefficients *)

F6s[α_]=Factor[GroebnerBasis[LL,{α},{a25,a35,L5,β},CoefficientDomain->RationalFunctions][[1]]]

G6s[β_]=-Factor[GroebnerBasis[LL,{β},{a25,a35,L5,α},CoefficientDomain->RationalFunctions][[1]]]

(* Below is indicated the algorithmic computation, for n = 5, of the function equations  
α = α5(β,s) and β = β5(α,s) *)

Factor[GroebnerBasis[Join[LL,{G6s[β]}],{α,β},{a25,a35,L5},CoefficientDomain->RationalFunctions][[2]]]

Solve[%==0,α]//Simplify

Factor[GroebnerBasis[Join[LL,{F6s[α]}],{β,α},{a25,a35,L5},CoefficientDomain->RationalFunctions][[2]]]

Solve[%==0,β]//Simplify