(* To generate the Malyshev polynomials (Subscript[F, m(n),s])(α)and (Subscript[G, m(n),s])(β) of degree m(n)by means of resultants, proceed, for n = even, as follows *)

(* define with Mathematica the following variables *)

s[α_,β_,k_]=1/2(-α^k-β^k+1-(-1)^k);
ss[α_,β_,k_]=1/2(α^k-β^k+1+(-1)^k);
F[α_,β_,0]=1;
FF[α_,β_,0]=1;
F[α_,β_,k_]:=(-1)^k/k!Det[Table[If[j>i,If[j==i+1,i,0],s[α,β,i-j+1]],{i,k},{j,k}]];
FF[α_,β_,k_]:=(-1)^k/k!Det[Table[If[j>i,If[j==i+1,i,0],ss[α,β,i-j+1]],{i,k},{j,k}]];
ϕ[k_,n_]:=Module[{m=(n-2)/2},Det[Table[If[j==k,-F[α,β,m+i],F[α,β,m+i-j]],{i,m+1},{j,m+1}]]];
ψ0[n_]:=Module[{m=(n-2)/2},Det[Table[FF[α,β,m+i-j+1],{i,m},{j,m}]]];
ψ1[n_]:=Module[{m=(n-2)/2},Det[Table[If[j==1,-FF[α,β,m+1+i],FF[α,β,m+i-j+1]],{i,m},{j,m}]]]

(* To get (Subscript[F, m(n),s])(α), insert xϵ{4,6,8,10,12, ...} into the following command-line and execute *)
(* n=x; Collect[Factor[Resultant[Factor[Sum[α^j ϕ[n/2-j,n],{j,0,n/2}]][[-1]],Factor[{(α+1-n s),-2}.{ψ0[n],ψ1[n]}][[-1]],β]][[-1]],α] *)

(* To get (Subscript[G, m(n),s])(β), insert xϵ{4,6,8,10,12, ...} into the following command-line and execute *)
(* n=x; Collect[Factor[Resultant[Factor[Sum[α^j ϕ[n/2-j,n],{j,0,n/2}]][[-1]],Factor[{(α+1-n s),-2}.{ψ0[n],ψ1[n]}][[-1]],α]][[-1]],β] *)

(* Examples *)

(* Calculate (Subscript[F, m(4),s])(α) *)

n=4; Collect[Factor[Resultant[Factor[Sum[α^j ϕ[n/2-j,n],{j,0,n/2}]][[-1]],Factor[{(α+1-n s),-2}.{ψ0[n],ψ1[n]}][[-1]],β]][[-1]],α]

(* Calculate (Subscript[G, m(4),s])(β) *)

n=4; Collect[Factor[Resultant[Factor[Sum[α^j ϕ[n/2-j,n],{j,0,n/2}]][[-1]],Factor[{(α+1-n s),-2}.{ψ0[n],ψ1[n]}][[-1]],α]][[-1]],β]

(* Calculate (Subscript[F, m(6),s])(α) *)

n=6; Collect[Factor[Resultant[Factor[Sum[α^j ϕ[n/2-j,n],{j,0,n/2}]][[-1]],Factor[{(α+1-n s),-2}.{ψ0[n],ψ1[n]}][[-1]],β]][[-1]],α]

(* Calculate (Subscript[G, m(6),s])(β) *)

n=6; Collect[Factor[Resultant[Factor[Sum[α^j ϕ[n/2-j,n],{j,0,n/2}]][[-1]],Factor[{(α+1-n s),-2}.{ψ0[n],ψ1[n]}][[-1]],α]][[-1]],β]

(* Remark: the cases of n = odd can be handled similarly, see Section 5 in [6] *)