Számítógépek a Matematika tanításában—9

DGS — Interaktív geometria

Szakaszfelezô

Alap(bázis)objektumok
Származtatott (derivált) objektumok

Az alapobjektumokat dinamikusan változtatva (pl Locator)  dinamikusan változnak a származtatott objektumok is.

Feladat Szakaszfelezô

Statikus ábra

A1={0,0};B1={3,0};C1={1,2};
Graphics[{Black, PointSize[.02],Point[{A1,B1,C1}],Line[{A1,B1,C1,A1}]}]

Graphics[{Black, PointSize[.02],Point[{A1,B1,C1}],Line[{A1,B1,C1,A1}],Red,Line[{C1,(A1+B1)/2}],Green,Point[(A1+B1)/2]}]

Dinamizálás:

Manipulate[Graphics[{Black, PointSize[.02],Point[{A1,B1,C0}],Line[{A1,B1,C0,A1}],Red,Line[{C0,(A1+B1)/2}],Green,Point[(A1+B1)/2]},PlotRange->{{-1,5},{-1,5}}],{C0,{0,1},{4,3},Locator}]

Szögfelezô

Adjuk meg az ABC csúcsú (sík)hsz belsô szögfelezôjét. Dinamizájuk az ábrát.

AR[Q_,P1_,P2_,{m_,n_}]:=Graphics[{Line[{P1,P2}],Line[{Q,(n P1+m P2)/(m+n)}]}]

Manipulate[Show[AR[{0,0},{-1,1},{1,1},{1,α}],AspectRatio->1,PlotRange->{{-1,3},{-1,3}}],{α,1,10,.1}]

Show[AR[{0,0},{-1,1},{1,1},{1,10}],AspectRatio->1,PlotRange->{{-1,3},{-1,3}}]

Szögfelezô: azt használjuk ki,  hogy a két oldal arányában osztja a szögfelezô a szemközti oldalt.

Bisector[P1_,P2_,P3_]:=Module[{le1=Norm[P2-P1],le2=Norm[P3-P1]},Line[{P1,(le2 P2+le1 P3)/(le1+le2)}]]

A1={0,0};B1={5,0};C1={4,3};

Graphics[{Line[{A1,B1}],Line[{B1,C1}],Line[{C1,A1}],Red,Bisector[A1,B1,C1]}]

Show[Graphics[{Line[{A1,B1}],Line[{B1,C1}],Line[{C1,A1}],Red,Bisector[A1,B1,C1],Bisector[B1,C1,A1],Bisector[C1,A1,B1]}],PlotRange->{{-1,6},{-1,6}}]

Dinamizálás: Manipulate +C0 ⟸ C1

Manipulate[Show[Graphics[{Line[{A1,B1}],Line[{B1,C0}],Line[{C0,A1}],Red,Bisector[A1,B1,C0],Bisector[B1,C0,A1],Bisector[C0,A1,B1]}],PlotRange->{{-1,6},{-1,6}}],{{C0,{3,4}},{0,0},{5,5},Locator}]

Summary

Plot, ListPlot, ContourPlot, ParametricPlot

Manipuate, Animante, Slider, Slider2D,  Locator

Kiegészítés a B csoport feladataihoz

IsoPrimeQ[z_]:=PrimeQ[z]∧Not[PrimeQ[z-2]]∧Not[PrimeQ[z+2]]

IPL=Select[Table[j,{j,510}],IsoPrimeQ]

Length[%]

TableForm[Table[{Style[j,Red],IPL[[j]]},{j,50}]]

g[x_]:=(((x^2)/(1-x^2))^(1/3))

A fgv def nem jó, mert (Subscript[D, h])=ℝ\{-1,1}, komplex aritmetika (!) ⟶pl. g2

Plot[g[x],{x,-2,2}]

g2[x_]:=Piecewise[{{((((x^2))/(1-x^2))^(1/3)) ,-1<=x<=1},{-((((x^2))/(x^2-1))^(1/3)),True}}]

Plot[g2[x],{x,-2,2},PlotPoints->100]

Limit[g2[x],x->∞]

Plot[g2[x],{x,0,20}]

{Limit[g2[x],x->-1,Direction->1],Limit[g2[x],x->-1,Direction->-1]}

Plot[g2[x],{x,-2,0}]

iplist=x/.Solve[D[g2[x],{x,2}]==0,x]

Plot[Evaluate[{g2[x],D[g2[x],x,x]}],{x,-4,4},ColorFunction->(If[(Evaluate[D[g2[x],{x,2}]]/.x->#1)>0,Red,Blue]&),ColorFunctionScaling->False,Epilog->{PointSize[.02],Green,Map[Point[{#,g2[#]}]&,iplist]},PlotPoints->1000]

M=100;

T1=Table[{Random[Real,{-1,1}],Random[Real,{-1,1}]},{M}]

InCircleQ[P_]:=Norm[P]≤1

InCircleQ[{1/2,1/2}]

InCircleQ[{1,-1}]

Length[Select[T1,InCircleQ]]/M

π/4.

Manipulate[Graphics[{Yellow,Disk[{0,0},1],Black,Point[Take[T1,n]]},Axes->True],{n,1,M,1}]